APEX TRAINING -2:

The following example shows how to create opportunity with a parent account.
public class ParentChildSample {
public static void InsertParentChild() {
Date dt = Date.today();
dt = dt.addDays(7);
Opportunity newOpportunity = new Opportunity(
Name='OpportunityWithAccountInsert',
StageName='Prospecting',
CloseDate=dt);
// Create the parent reference.
// Used only for foreign key reference
// and doesn't contain any other fields.
Account accountReference = new Account(
MyExtID__c='SAP111111');
newOpportunity.Account = accountReference;
// Create the Account object to insert.
// Same as above but has Name field.
// Used for the insert.
Account parentAccount = new Account(
Name='Hallie',
MyExtID__c='SAP111111');
// Create the account and the opportunity
Database.SaveResult[] results = Database.insert(new SObject[] {
parentAccount, newOpportunity });
// Check results.
for (Integer i = 0; i < results.size(); i++) {
if (results[i].isSuccess()) {
System.debug('Successfully created ID: '
+ results[i].getId());
} else {
System.debug('Error: could not create sobject '
+ 'for array element ' + i + '.');
System.debug(' The error reported was: '
+ results[i].getErrors()[0].getMessage() + '\n');
}
}
}
}

This next example uses the Database.upsert to upsert a collection of leads that are passed in.
/* This class demonstrates and tests the use of the
* partial processing DML operations */
public class DmlSamples {
/* This method accepts a collection of lead records and
creates a task for the owner(s) of any leads that were
created as new, that is, not updated as a result of the upsert
operation */
public static List<Database.upsertResult> upsertLeads(List<Lead> leads) {
/* Perform the upsert. In this case the unique identifier for the
insert or update decision is the Salesforce record ID. If the
record ID is null the row will be inserted, otherwise an update
will be attempted. */
List<Database.upsertResult> uResults = Database.upsert(leads,false);
/* This is the list for new tasks that will be inserted when new
leads are created. */
List<Task> tasks = new List<Task>();
for(Database.upsertResult result:uResults) {
if (result.isSuccess() && result.isCreated())
tasks.add(new Task(Subject = 'Follow-up', WhoId = result.getId()));
}
/* If there are tasks to be inserted, insert them */
Database.insert(tasks);
return uResults;
}

}

@isTest

private class DmlSamplesTest {

public static testMethod void testUpsertLeads() {

/* We only need to test the insert side of upsert */

List<Lead> leads = new List<Lead>();

/* Create a set of leads for testing */

for(Integer i = 0;i < 100; i++) {

leads.add(new Lead(LastName = 'testLead', Company = 'testCompany'));

}

/* Switch to the runtime limit context */

Test.startTest();

/* Exercise the method */

List<Database.upsertResult> results = DmlSamples.upsertLeads(leads);

/* Switch back to the test context for limits */

Test.stopTest();

/* ID set for asserting the tasks were created as expected */

Set<Id> ids = new Set<Id>();

/* Iterate over the results, asserting success and adding the new ID

to the set for use in the comprehensive assertion phase below. */

for(Database.upsertResult result:results) {

System.assert(result.isSuccess());

ids.add(result.getId());

}

/* Assert that exactly one task exists for each lead that was inserted. */

for(Lead l:[SELECT Id, (SELECT Subject FROM Tasks) FROM Lead WHERE Id IN :ids]) {

System.assertEquals(1,l.tasks.size());

}

}

}